Unity Shader: 理解Stencil buffer并将它用于一些实战案例（描边，多边形填充，反射区域限定，阴影体shadow volume阴影渲染）

已于 2022-12-06 23:26:53 修改
阅读量1.7w 收藏 88
点赞数 40
分类专栏： Shader 文章标签： Shader Stencil buffer 模板测试 shadow volume 模板缓冲
于 2019-01-11 22:46:21 首次发布
版权声明：本文为博主原创文章，遵循 CC 4.0 BY-SA 版权协议，转载请附上原文出处链接和本声明。
本文链接：https://blog.csdn.net/liu_if_else/article/details/86316361
版权

本文示例项目Github连接：https://github.com/liu-if-else/UnityStencilBufferUses

最近有两次被人问到stencil buffer的用法，回答的含糊其辞，这两天研究了下它并总结出此文。

文章目录

 
1,Stencil buffer在OpenGL/Unity 渲染管线中的角色

为什么叫stencil 模板

stencil是印刷工业中的版面模子，模子上抠出需要的图案，然后将模子盖在要被印刷的材质上，对洞涂或喷绘颜色。

如果将屏幕上所有像素想象成一串连续的0组成的矩形，那么stencil buffer的作用就是将某些0变为1，2，3 … 255，在每个pass中可以决定只渲染某个特定stencil值的像素并抛弃对其他非该值像素的操作，就像一块模板一样扣住了所有像素，并只对当前stencil值的洞洞进行喷绘。

stencil与depth

stencil buffer与depth buffer一样，都是缓冲区，存在于显存内的某一片区域中。据wikipedia上解释，目前的显卡架构中，stencil buffer与depth buffer是在一起的，比如在depth/stencil缓冲区某个32位的区域中，有24位记录着像素A的depth数据，紧接着8位记录着像素A的stencil数据。也许就是由于它们连接如此紧密，在stencil test中可以获取到Z test的结果。在Unity中新建一个RenderTexture也可以通过设定深度值的位数来选择开启/关闭stencil buffer。

stencil测试在管线中的位置与它的写入与读取

在OpenGL渲染管线中，在片段着色器fragment shader之后，Blending混融之前有三个测试操作环节: scissor test(unity好像用不了)，Stencil Test和Z-Test。
在Stencil Test环节，可通过使用关键字Comp读stencil值并与Ref值进行比较，通过Keep,Zero,Incr…对stencil进行写入，所有关键字说明请看Unity官网：

            Stencil {
            	//当前像素stencil值与0进行比较
                Ref 0           //0-255
                //测试条件：测试是否相等
                Comp Equal     //default:always
                //如果测试通过对此stencil值进行的写入操作：保持当前stencil值
                Pass keep       //default:keep
                //如果测试失败对此stencil值进行的写入操作：保持当前stencil值
                Fail keep       //default:keep
                //如果深度测试失败对此stencil值进行的写入操作：循环递增
                ZFail IncrWrap  //default:keep
            }

 
 
2,使用Stencil buffer进行描边

代码

Shader "Unlit/StentilOutline"
{
	Properties
	{
		_MainTex ("Texture", 2D) = "white" {}
	}
	SubShader
	{
		Tags { "RenderType"="Opaque" }
		LOD 100
        Stencil {
             Ref 0          //0-255
             Comp Equal     //default:always
             Pass IncrSat   //default:keep
             Fail keep      //default:keep
             ZFail keep     //default:keep
        }

		Pass
		{
			CGPROGRAM
			#pragma vertex vert
			#pragma fragment frag
			// make fog work
			#pragma multi_compile_fog
			
			#include "UnityCG.cginc"

			struct appdata
			{
				float4 vertex : POSITION;
				float2 uv : TEXCOORD0;
			};

			struct v2f
			{
				float2 uv : TEXCOORD0;
				UNITY_FOG_COORDS(1)
				float4 vertex : SV_POSITION;
			};

			sampler2D _MainTex;
			float4 _MainTex_ST;
			
			v2f vert (appdata v)
			{
				v2f o;
				o.vertex = UnityObjectToClipPos(v.vertex);
				o.uv = TRANSFORM_TEX(v.uv, _MainTex);
				UNITY_TRANSFER_FOG(o,o.vertex);
				return o;
			}
			
			fixed4 frag (v2f i) : SV_Target
			{
				// sample the texture
				fixed4 col = tex2D(_MainTex, i.uv);
				// apply fog
				UNITY_APPLY_FOG(i.fogCoord, col);
			    //return fixed4(1,1,0,1);
                return col;
			}
			ENDCG
		}

        Pass
        {
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            // make fog work
            #pragma multi_compile_fog
            
            #include "UnityCG.cginc"

            struct appdata
            {
                float4 vertex : POSITION;
                float4 normal: NORMAL;
                float2 uv : TEXCOORD0;
            };

            struct v2f
            {
                float2 uv : TEXCOORD0;
                UNITY_FOG_COORDS(1)
                float4 vertex : SV_POSITION;
            };

            sampler2D _MainTex;
            float4 _MainTex_ST;
            
            v2f vert (appdata v)
            {
                v2f o;
                o.vertex=v.vertex+normalize(v.normal)*0.01f;
                o.vertex = UnityObjectToClipPos(o.vertex);
                o.uv = TRANSFORM_TEX(v.uv, _MainTex);
                UNITY_TRANSFER_FOG(o,o.vertex);
                return o;
            }
            
            fixed4 frag (v2f i) : SV_Target
            {
                // sample the texture
                fixed4 col = tex2D(_MainTex, i.uv);
                // apply fog
                UNITY_APPLY_FOG(i.fogCoord, col);
                return fixed4(1,1,1,1);
            }
            ENDCG
        }
	}
}

说明

        Stencil {
             Ref 0          //0-255
             Comp Equal     //default:always
             Pass IncrSat   //default:keep
             Fail keep      //default:keep
             ZFail keep     //default:keep
        }

buffer的值在当前帧结束前是不清除的，所以它可以跨越不同的shader与pass。Stencil结构写在Subshader中，那么下面的所有pass中的stencil test都按此运行。理想环境下，第一个pass渲染前屏幕上所有像素的stencil值都是0，在该pass的fragment shader结束后，所有进行了渲染的像素都通过了Ref 0和Comp Equal的测试，并执行Pass IncrSat将stencil值加1。

...
                o.vertex=v.vertex+normalize(v.normal)*0.01f;
...

第二个pass中，将顶点进行进行了放大。进行同样的stencil测试，上一个pass渲染过的像素stencil值已经变为1，无法通过Ref 0+Comp Equal测试，那么现在只会在放大后的既是stencil值仍然为0的区域进行渲染。

...
                return fixed4(1,1,1,1);
...

对第二个pass通过测试的像素给予描边颜色。

效果

图1：使用StencilPerPassOutline.shader
图1：使用StencilPerPassOutline.shader
图2：使用StencilOutline.shader
图2：使用StencilOutline.shader
 
 

3,使用stencil buffer进行多边形填充

这个效果与Unity官网中介绍stencil的第一个example shader类似，通过stencil值对几何体交叉区域进行判定与渲染。

代码

Shader "Unlit/PolygonsBeta"
{
    Properties
    {
        _MainTex ("Texture", 2D) = "white" {}
    }
    SubShader
    {
        Tags { "RenderType"="Opaque" }
        LOD 100

        CGINCLUDE
        #include "UnityCG.cginc"
        struct appdata
        {
            float4 vertex : POSITION;
            float2 uv : TEXCOORD0;
        };

        struct v2f
        {
            float2 uv : TEXCOORD0;
            UNITY_FOG_COORDS(1)
            float4 vertex : SV_POSITION;
        };

        sampler2D _MainTex;
        float4 _MainTex_ST;
        
        v2f vert (appdata v)
        {
            v2f o;
            o.vertex = UnityObjectToClipPos(v.vertex);
            o.uv = TRANSFORM_TEX(v.uv, _MainTex);
            UNITY_TRANSFER_FOG(o,o.vertex);
            return o;
        }
        ENDCG

        Pass
        {
            Stencil {
                Ref 0           //0-255
                Comp always     //default:always
                Pass IncrWrap       //default:keep
                Fail keep       //default:keep
                ZFail IncrWrap  //default:keep
            }

            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            // make fog work
            #pragma multi_compile_fog

            fixed4 frag (v2f i) : SV_Target
            {
                // sample the texture
                fixed4 col = tex2D(_MainTex, i.uv);
                // apply fog
                UNITY_APPLY_FOG(i.fogCoord, col);
                return fixed4(0,0,0,0);
            }
            ENDCG
        }
        
        Pass
        {
            Stencil {
                Ref 2           //0-255
                Comp Equal     //default:always
                Pass keep       //default:keep
                Fail keep       //default:keep
                ZFail keep  //default:keep
            }
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            // make fog work
            #pragma multi_compile_fog
            
            #include "UnityCG.cginc"

            fixed4 frag (v2f i) : SV_Target
            {
                // sample the texture
                fixed4 col = tex2D(_MainTex, i.uv);
                // apply fog
                UNITY_APPLY_FOG(i.fogCoord, col);
                return fixed4(0.2,0.2,0.2,1);
            }
            ENDCG
        }

        Pass
        {
            Stencil {
                Ref 3          //0-255
                Comp equal     //default:always
                Pass keep   //default:keep
                Fail keep      //default:keep
                ZFail keep  //default:keep
            }
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            // make fog work
            #pragma multi_compile_fog
            
            #include "UnityCG.cginc"

            fixed4 frag (v2f i) : SV_Target
            {
                // sample the texture
                fixed4 col = tex2D(_MainTex, i.uv);
                // apply fog
                UNITY_APPLY_FOG(i.fogCoord, col);
                return fixed4(0.6,0.6,0.6,1);
            }
            ENDCG
        }

        Pass
        {
            Stencil {
                Ref 4          //0-255
                Comp equal     //default:always
                Pass keep   //default:keep
                Fail keep      //default:keep
                ZFail keep  //default:keep
            }
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            // make fog work
            #pragma multi_compile_fog
            
            #include "UnityCG.cginc"

            fixed4 frag (v2f i) : SV_Target
            {
                // sample the texture
                fixed4 col = tex2D(_MainTex, i.uv);
                // apply fog
                UNITY_APPLY_FOG(i.fogCoord, col);
                return fixed4(1,1,1,1);
            }
            ENDCG
        }
    }
}

说明

第一个pass渲染一个几何体，不论任何情况都通过测试并对它所覆盖的像素区域stencil值加1，后三个pass分别只对stencil值为2，3，4的区域进行渲染。

效果

图3：使用PolygonsBeta.shader
图3：使用PolygonsBeta.shader

图4：使用polygons.shader
图4：使用polygons.shader

上图是结合此shader与以前文章里的阿基米德螺旋线算法放飞想象力的结果-_-。感觉用这招做Logo潜力好大…

 
 
4,用stencil buffer进行反射区域限定

此用法主要是辅助一个反射shader，可以比较简单的模拟出一个镜面效果。

代码

Shader "Unlit/TwoPassReflection"
{
	Properties
	{
		_MainTex ("Texture", 2D) = "white" {}
	}
	SubShader
	{
		Tags { "RenderType"="Opaque" "Queue"="Geometry" }
		LOD 100

		Pass
		{
			CGPROGRAM
			#pragma vertex vert
			#pragma fragment frag
			// make fog work
			#pragma multi_compile_fog
			
			#include "UnityCG.cginc"

			struct appdata
			{
				float4 vertex : POSITION;
				float2 uv : TEXCOORD0;
			};

			struct v2f
			{
				float2 uv : TEXCOORD0;
				UNITY_FOG_COORDS(1)
				float4 vertex : SV_POSITION;
			};

			sampler2D _MainTex;
			float4 _MainTex_ST;
			
			v2f vert (appdata v)
			{
				v2f o;
				o.vertex = UnityObjectToClipPos(v.vertex);
				o.uv = TRANSFORM_TEX(v.uv, _MainTex);
				UNITY_TRANSFER_FOG(o,o.vertex);
				return o;
			}
			
			fixed4 frag (v2f i) : SV_Target
			{
				// sample the texture
				fixed4 col = tex2D(_MainTex, i.uv);
				// apply fog
				UNITY_APPLY_FOG(i.fogCoord, col);
				return col;
			}
			ENDCG
		}

        Pass
        {
            Stencil {
                Ref 1          //0-255
                Comp Equal     //default:always
                Pass keep   //default:keep
                Fail keep      //default:keep
                ZFail keep     //default:keep
            }
            ZTest Always
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            // make fog work
            #pragma multi_compile_fog
            
            #include "UnityCG.cginc"

            struct appdata
            {
                float4 vertex : POSITION;
                float2 uv : TEXCOORD0;
                float4 normal: NORMAL;
            };

            struct v2f
            {
                float2 uv : TEXCOORD0;
                UNITY_FOG_COORDS(1)
                float4 vertex : SV_POSITION;
            };

            sampler2D _MainTex;
            float4 _MainTex_ST;
            
            v2f vert (appdata v)
            {
                v2f o;
                v.vertex.xyz=reflect(v.vertex.xyz,float3(-1.0f,0.0f,0.0f));
                v.vertex.xyz=reflect(v.vertex.xyz,float3(0.0f,1.0f,0.0f));
                v.vertex.x+=1.5f;
                o.vertex = UnityObjectToClipPos(v.vertex);
                o.uv = TRANSFORM_TEX(v.uv, _MainTex);
                UNITY_TRANSFER_FOG(o,o.vertex);
                return o;
            }
            
            fixed4 frag (v2f i) : SV_Target
            {
                // sample the texture
                fixed4 col = tex2D(_MainTex, i.uv);
                // apply fog
                UNITY_APPLY_FOG(i.fogCoord, col);
                return col;
            }
            ENDCG
        }
	}
}

Shader "Unlit/Mirror"
{
	Properties
	{
		_MainTex ("Texture", 2D) = "white" {}
	}
	SubShader
	{
		Tags { "RenderType"="Opaque" "Queue"="Geometry-1" }
		LOD 100

        Stencil {
            Ref 0          //0-255
            Comp always     //default:always
            Pass IncrSat   //default:keep
            Fail keep      //default:keep
            ZFail keep     //default:keep
        }

		Pass
		{
			CGPROGRAM
			#pragma vertex vert
			#pragma fragment frag
			// make fog work
			#pragma multi_compile_fog
			
			#include "UnityCG.cginc"

			struct appdata
			{
				float4 vertex : POSITION;
				float2 uv : TEXCOORD0;
			};

			struct v2f
			{
				float2 uv : TEXCOORD0;
				UNITY_FOG_COORDS(1)
				float4 vertex : SV_POSITION;
			};

			sampler2D _MainTex;
			float4 _MainTex_ST;
			
			v2f vert (appdata v)
			{
				v2f o;
				o.vertex = UnityObjectToClipPos(v.vertex);
				o.uv = TRANSFORM_TEX(v.uv, _MainTex);
				UNITY_TRANSFER_FOG(o,o.vertex);
				return o;
			}
			
			fixed4 frag (v2f i) : SV_Target
			{
				// sample the texture
				fixed4 col = tex2D(_MainTex, i.uv);
				// apply fog
				UNITY_APPLY_FOG(i.fogCoord, col);
				return fixed4(0.2f,0.2f,0.2f,1.0f);
			}
			ENDCG
		}
	}
}

说明

在TwoPassReflection.shader中，第一个pass正常渲染模型，第二个pass对顶点进行了一个简单的反射，并将ZTest设为always，然后将一个quad放入本体和倒影之间，它的效果是这样的：
图5：使用TwoPassReflection.shader(无stencil测试)
图5：使用TwoPassReflection.shader，无mirror.shader

倒影超出了想要的范围。解决这一问题，在quad上使用mirror.shader将quad覆盖的像素stencil值改为1，并在TwoPassReflection第二个pass中约定只在stencil值为1的区域中渲染。

效果

图5：quad使用mirror.shader
图6：quad使用mirror.shader

这里有个前提是mirror必须在倒影之前渲染以先将反射区域的stencil值标记好。

 
 
5,阴影体shadow volume阴影渲染

说明

shadow volume阴影体算法是将‘遮光体’遮挡光源后产生的阴影实例为一个几何体，对在该阴影几何体的渲染过程中找出应该渲染阴影效果的像素。
图6：圆柱阴影体
图7：圆柱阴影体

检测手段有几种，本案例shader采用的是Depth Fail，也叫Carmack’s reverse方法的思路。它的思想与步骤如下：

1，在一般物体渲染后，渲染阴影体，第一个pass cull front，渲染内侧，在stencil测试阶段如果发现深度测试失败，说明该像素在阴影体内部表面或阴影体外部表面与视角之间有发生遮挡，将该像素stencil值加1。

2，第二个pass cull back，渲染外侧，如果有深度测试失败，则说明该像素在阴影体外部表面与视角之间有发生遮挡，将该像素stencil值减1。

3，经过两个pass的stencil操作，只有在阴影体内部的物体且它遮挡住阴影体内部表面的部分的stencil值为1。对阴影体内stencil值为1的像素进行渲染。

本文中的shader只为展示stencil buffer在此技术中的角色，缺乏正确的阴影体网格或它的动态生成手段，粗暴的用Unity默认几何体中的圆柱体模拟一个阴影体，并且算法中也没有考虑被阴影覆盖的物体自身的阴影体的问题以及其他细节问题。

代码

Shader "Unlit/SV_DepthFailBeta"
{
    Properties
    {
    }
    SubShader
    {
        Tags { "RenderType"="Opaque" "Queue"="Geometry+1"}  //在渲染所有阴影体内物体后再渲染阴影体
        LOD 100
        
        CGINCLUDE       //三个pass内着色器内容相同
        #include "UnityCG.cginc"
        struct appdata
        {
            float4 vertex : POSITION;
        };

        struct v2f
        {
            UNITY_FOG_COORDS(1)
            float4 vertex : SV_POSITION;
        };

        v2f vert (appdata v)
        {
            v2f o;
            o.vertex = UnityObjectToClipPos(v.vertex);
            UNITY_TRANSFER_FOG(o,o.vertex);
            return o;
        }
        
        fixed4 frag (v2f i) : SV_Target
        {
            // apply fog
            UNITY_APPLY_FOG(i.fogCoord, col);
            return fixed4(0.3,0.3,0.3,1);           //影子颜色
        }
        ENDCG

        Pass
        {
            Cull Front          //阴影体内侧像素Z测试失败，stencil值加1
            Stencil {           
                Ref 0           //0-255
                Comp always     //default:always
                Pass keep       //default:keep
                Fail keep       //default:keep
                ZFail IncrWrap  //default:keep
            }

            ColorMask 0         //关闭color buffer写入
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            // make fog work
            #pragma multi_compile_fog
            ENDCG
        }
        
        Pass
        {
            Cull Back           //阴影体外侧像素Z测试失败，stencil值减1
            Stencil {
                Ref 0           //0-255
                Comp always     //default:always
                Pass keep       //default:keep
                Fail keep       //default:keep
                ZFail DecrWrap  //default:keep
            }
            ColorMask 0         //关闭color buffer写入
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            // make fog work
            #pragma multi_compile_fog
            ENDCG
        }

        Pass
        {
            Cull Back          //经过前两个pass，stencil值为1的值为在此阴影体内被阴影覆盖的像素
            Stencil {
                Ref 1          //0-255
                Comp equal     //default:always
                Pass keep   //default:keep
                Fail keep      //default:keep
                ZFail keep  //default:keep
            }
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            // make fog work
            #pragma multi_compile_fog
            ENDCG
        }
    }
}

效果

图7：使用SV_DepthFailBeta.shader
图8：使用SV_DepthFailBeta.shader

参考：

Shadow Volume–Depth Fail, wikipedia:
https://en.wikipedia.org/wiki/Shadow_volume#Depth_fail

Creating Reflections and Shadows Using Stencil, BuffersMark J. Kilgard:
https://www2.cs.duke.edu/courses/spring15/cps124/classwork/14_buffers/stencil.pdf

Stencil Shadow Volume, OGL:
http://ogldev.atspace.co.uk/www/tutorial40/tutorial40.html

ShaderLab: Stencil, Unity:
https://docs.unity3d.com/Manual/SL-Stencil.html

Simon F’s answer to topic of ‘Uses for Stencil Buffer’ :
https://computergraphics.stackexchange.com/questions/5046/uses-for-stencil-buffer

本文示例项目Github连接：
https://github.com/liu-if-else/UnityStencilBufferUses

本文英文版：
https://liu-if-else.github.io/stencil-buffer’s-uses-in-unity3d/

维护日志：
2020-8-16：review

liu_if_else
关注
  • 40
    点赞
  • 踩
  • 88
    收藏
    觉得还不错? 一键收藏
  • 2
    评论
专栏目录
阴影边界柔化插件Shadow Softener.unitypackage
04-15
unity阴影边界柔化插件，非常好用，只需要将shader放到接受阴影的地面上就可以，简单方便可操作，自用插件，喜欢的快快下载呀
Stencil Buffer&Stencil Test
taoqilin的专栏
07-12 1476
转载出处：http://blog.csdn.net/u011047171 Stencil Buffer&Stencil Test 在开始前先吐槽下unity的官方文档，说实话关于stencil ，官方文档真的是可以不要了，除了记流水账般解释了下各个参数的作用，作为例子的shader也是让人一头雾水，整个文档看下来，你发觉stencil是用来干嘛的，怎么操作，仍然不知道。
渲染管线漫谈（二）
最新发布
听老罗娓娓道来
03-05 618
为了确保最广泛的兼容性，开发者在设计使用模板测试的应用程序时，应该考虑到这些潜在的硬件限制，并在可能的情况下提供后备方案或不同的渲染路径。在使用模板测试时，开发者需要权衡其带来的好处和潜在的成本。这段代码的意思是，对于每个像素，无论模板测试的结果如何（Comp always），都将模板缓冲区中的值设置为1（Ref 1），并且在渲染时替换模板缓冲区的值（Pass replace）。大多数现代GPU支持至少8位的模板缓冲区，但在一些较旧或低端的硬件上，模板缓冲区的位深可能小于8位，这限制了可用的模板值范围。
Unity shader实现多光源漫反射以及阴影
08-18
主要为大家详细介绍了shader实现多光源漫反射以及阴影，文中示例代码介绍的非常详细，具有一定的参考价值，感兴趣的小伙伴们可以参考一下
Unity Shader unity文档学习笔记(十六)：模板测试StencilTest UGUI Mask遮罩实现
qq_43204246的博客
06-24 590
UGUI的Mask也是通过Stencil实现的 Stencil的所有参数如下 Stencil { Ref 1//Reference Value ReadMask 255 WriteMask 255 Comp Always //Comparison Function Pass Replace Fail Keep ZFail Replace } Ref 就是参考值，当参数允许赋值时，会把参考值赋给当前像素 ReadMask 对当前参考值和已有值进行ma
用imspost制作catia后处理_利用StencilBuffer实现局部后处理描边
weixin_39996739的博客
11-20 1095
前言本文主要介绍了如何使用StencilBuffer实现局部后处理描边,主要分为三个部分,对不透明物体的描边,对透明度测试物体的描边和对透明度混合物体的描边.起因是看到了一篇关于口袋妖怪X/Y的分享文章,里面介绍的描边方式是用的后处理方式,是根据法线,顶点色和StencilBuffer共同作用下进行描边,StencilBuffer在这里主要是辅助作用,对于其他方式不容易获取的描边,通过Stenci...
【Unity Shader】关于Stencil的理解小记
alicelise的博客
04-24 4901
写在前面：本文只介绍Stencil最基本的三种参数：Ref Comp Pass ，其他的略略带过。 碎碎念：之前用过Stencil，但是没有完全理解，原因在于虽然理解了每项的意思，但是实际的使用效果不如人意，最后得出的结果纯靠运气试出来的。昨晚按照渲染流程走了一遍，豁然开朗，感觉自己好瓜皮qaq Stencil简介 Stencil是模板测试的意思，通常写在Pass里面最开头，CGPROGRAM之前。 stencil完整语法格式如下： stencil｛ Ref referenceValue ReadM.
Stencil在Unity中的使用
asitini的博客
01-03 9353
Stencil用于在渲染时保留和抛弃像素 Stencil对应的材质组件在Unity中的显示如图： Ref ReferenceValue 对应组件中的Stencil ID由程序自己设定，用于和缓冲（Stencil Buffer）中的值相比较，比较的方式在Stencil Comparison中设定，满足条件则渲染出来（保留）。 Stencil Comparison 渲染时判断是否保留的条件。将r...
【Unity3d Shader】模板缓冲区(Stencil buffer)
PangNanGua的专栏
11-05 2024
模版缓冲（stencil buffer）或印模缓冲，是在OpenGL三维绘图等计算机图像硬件中常见的除颜色缓冲、像素缓冲、深度缓冲之外另一种数据缓冲。
Unity ShaderLab中的模板测试（Stencil）
u012861978的专栏
11-13 262
模板测试 发生在片元着色器之后的逐片元操作阶段：透明度测试——>——>深度测试——>透明度混合。
Unity中Shader实现模板测试Stencil
楠溪泽岸的博客
09-20 773
Unity中Shader实现模板测试
Canvas_Shadow_shadow_Unity阴影Shader_toweromb_SHADER_unity_
10-04
半透明接收点光源阴影的shader
Unity Shader实现描边OutLine效果
12-23
本文实例为大家分享了Unity Shader实现描边OutLine效果的具体代码，供大家参考，具体内容如下 Shader实现描边流程大致为：对模型进行2遍（2个pass）绘制，第一遍（描边pass）在vertex shader中对模型沿顶点法线方向...
Unity Stencil模版测试的简单应用
qq_41328432的博客
08-28 224
通常情况下，Stencil值在绘制对象时被设置，然后在随后的绘制步骤中用来决定哪些像素应该被绘制，哪些像素应该被忽略，或者以不同的方式处理。在我们的屏幕上，每一个像素都有自己的stencil值，默认是0。在实际应用中，我们可以通过stencil test来改变像素的stencil值，也可以通过stencil test来剔除一些像素的渲染。在创建一个一样的，命名为Stencil2，Stencil的Value设为2，其他一样。这里填的是Replace，代表通过之后，用Ref的值替换当前缓冲的值。
UnityShader 模板测试（Stencil）
qq_40181217的博客
11-08 1028
UnityShader 模板测试（Stencil）写在开头什么是模板测试Stencil buffer是个啥如何使用模板测试的方式实现一个遮罩效果1.创建一个模板2.和模板进行比较示例代码效果图Stencil 配置说明RefReadMaskWriteMaskCompPass ，Fail ， ZFail结语 写在开头 最近因为项目上的需要，作为一个小白只能硬着头皮研究了unityshader模板测试的相关资料。出于记录和分享的目的，也为了对这些天的研究做个总结方便后面需要的时候查看便写了本篇文章。本人技术粗浅，
Unity Shader - ShaderLab: Stencil 模板（缓存）
Jave.Lin 的学习笔记
07-08 3470
目录：Unity Shader - 知识点目录（先占位，后续持续更新） 原文：[目录：Unity Shader - 知识点目录（先占位，后续持续更新） 原文：Materials, Shaders & Textures 版本：2019.1](https://docs.unity3d.com/Manual/Shaders.html) 版本：2019.1 ShaderLab: Stencil 模...
Unity shader的StencilTest、ZTest与半透明渲染
u012740992的专栏
03-24 1759
着色器完成顶点编程和片元编程操作之后得到的颜色值，最后像素能不能够渲染出来还要经过最后一步逐片元操作，其中包括模板测试，深度测试等，只有通过了测试的像素点颜色才有资格进入颜色缓冲进行覆盖写入或者与已有颜色进行混合，从而被GPU渲染出来进入我们的视野。 其实Stencil Buffer和Z Buffer就是一类东西，其目的都是为这个像素点的颜色缓冲区值服务，不过是其记录的数值作用目的不同。 模板缓...
unity-shader stencil（模板测试）的基本应用
木马人
05-03 1195
先看效果，后上代码，最后解释： （1）使用stencil，控制球体显示在墙体Cube上：scene中位置排序：相机->墙体Cube->球体->背景BG （2）在game中的效果：球体->墙体Cube->背景BG Shader "Unlit/stencil_BG01" { Properties { _MainTex ("Texture"...
StencilBuffer模板缓冲
安都奕雨的博客
04-10 741
1、Stencil buffer概念： 屏幕平面好比一块大的平面，然后每个像素都有自己对应的stencil值，可以把他理解为一个数字标记，然后所有像素的初始默认stencil值都是0 这个时候如果想用到Stencil Buffer，那么就要去改变这些像素的值来舍弃或保留这些像素，相当于去判断渲染哪些像素 stencil buffer其实是zBuffer其中的一部分，StencilTest在ZTest之前，两者紧密联系，存在于显存内的某一片区域中。目前的显卡架构中，比如在depth/stencil缓冲区某个
unity shader 只渲染阴影
07-28
Unity Shader可以通过对材质进行设置，只渲染阴影。具体的实现方法如下： 1. 在Unity中创建一个新的Shader，并选择合适的渲染模式。可以选择使用Forward或Deferred渲染模式，具体选择要根据项目需求来确定。 2. 在Shader中添加一个属性，用于接收阴影贴图。可以使用Unity自带的_ShadowMap属性来接收场景中的阴影贴图。 3. 在顶点着色器中，将顶点的位置转换到裁剪空间中，以便在片元着色器中进行阴影的计算。 4. 在片元着色器中，使用接收到的阴影贴图对当前片元进行阴影的计算。根据阴影贴图中的透明度值，可以控制阴影的强度。 5. 如果需要设置其他阴影参数（如颜色、方向等），可以在Shader中添加相应的属性，并在片元着色器中进行相关计算。 6. 将创建好的Shader应用到需要渲染阴影的对象的材质上。 通过以上步骤，可以将Unity中的Shader设置为只渲染阴影。这样，对象在渲染时只会显示阴影部分，而不会渲染其他的物体表面。这种方法可以用于实现例如投影纹理等特殊效果，以及在游戏中实现只渲染阴影的需求。

“相关推荐”对你有帮助么？

  • 非常没帮助
  • 没帮助
  • 一般
  • 有帮助
  • 非常有帮助
提交
评论 2
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包
实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值